daily_automated

trunk/Arduino/libraries/Ticker/LICENSE

@@ -0,0 +1,21 @@
+MIT License
+
+Copyright (c) 2017 Stefan Staub
+
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in all
+copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+SOFTWARE.

trunk/Arduino/libraries/Ticker/README.md

@@ -0,0 +1,175 @@
+# Arduino Ticker Library v3.1.x
+
+The **Arduino Ticker Library** allows you to create easily Ticker callbacks, which can call a function in a predetermined interval. You can change the number of repeats of the callbacks, if repeats is 0 the ticker runs in endless mode. Works like a "thread", where a secondary function will run when necessary. The library use no interupts of the hardware timers and works with the **micros() / millis()** function. You are not (really) limited in the number of Tickers.
+
+## New in v2.0
+- You can determine the number of repeats, instead of modes.
+- The internal resolution is now **micros()**, this works with intervals up to 70 minutes. For longer intervals you can change the resolution to **millis()**. ``` Ticker tickerObject(callbackFunction, 1000, 0, MILLIS) ```
+- unified data types and smaller improvments
+
+## New in v2.1
+- You can change the interval time to microseconds. ``` Ticker tickerObject(callbackFunction, 100, 0, MICROS_MICROS) // interval is now 100us```
+- smaller improvments
+
+## New in v3.0
+- radical simplified API
+- generally you have to declare all settings in the constructor
+- deleted many set and get functions
+- if you need former functionality please use the version 2.1
+
+## New in v3.1
+- added interval function
+
+## Installation
+
+1. "Download":https://github.com/sstaub/Ticker/archive/master.zip the Master branch from GitHub.
+2. Unzip and modify the folder name to "Ticker"
+3. Move the modified folder on your Library folder (On your `Libraries` folder inside Sketchbooks or Arduino software).
+
+
+## How to use
+
+First, include the TimerObject to your project:
+
+```
+#include "Ticker.h"
+```
+
+Now, you can create a new object in setup():
+
+```
+Ticker tickerObject(callbackFunction, 1000); 
+tickerObject.start(); //start the ticker.
+```
+
+In your loop(), add:
+
+```
+tickerObject.update(); //it will check the Ticker 
+and if necessary, it will run the callback function.
+```
+
+
+## IMPORTANT
+If you use delay(), the Ticker will be ignored! You cannot use delay() command with the TimerObject. Instead of using delay, you can use the Ticker itself. For example, if you need that your loop run twice per second, just create a Ticker with 500 ms. It will have the same result that delay(500), but your code will be always state.
+
+## Example
+
+Complete example. Here we created five timers, you can run it and test the result in the Serial monitor and the on board LED.
+
+```
+#include "Ticker.h"
+
+void printMessage();
+void printCounter();
+void printCountdown();
+void blink();
+void printCountUS();
+
+bool ledState;
+int counterUS;
+
+Ticker timer1(printMessage, 0, 1); // once, immediately 
+Ticker timer2(printCounter, 1000, MILLIS); // internal resolution is milli seconds
+Ticker timer3(printCountdown, 1000, 5); // 5 times, every second
+Ticker timer4(blink, 500); // changing led every 500ms
+Ticker timer5(printCountUS, 100, 0, MICROS_MICROS); // the interval time is 100us and the internal resolution is micro seconds
+
+
+void setup() {
+  pinMode(LED_BUILTIN, OUTPUT);
+  Serial.begin(9600);
+  delay(2000);
+  timer1.start();
+  timer2.start();
+  timer3.start();
+  timer4.start();
+  timer5.start();
+  }
+
+void loop() {
+  timer1.update();
+  timer2.update();
+  timer3.update();
+  timer4.update();
+  timer5.update();
+  if (timer4.counter() == 20) timer4.interval(200);
+  if (timer4.counter() == 80) timer4.interval(1000);
+  }
+
+void printCounter() {
+  Serial.print("Counter ");
+  Serial.println(timer2.counter());
+  }
+
+void printCountdown() {
+  Serial.print("Countdowm ");
+  Serial.println(5 - timer3.counter());
+  }
+
+void printMessage() {
+  Serial.println("Hello!");
+  }
+
+void blink() {
+  digitalWrite(LED_BUILTIN, ledState);
+  ledState = !ledState;
+  }
+
+void printCountUS() {
+  counterUS++;  
+  if (counterUS == 10000) {
+    Serial.println("10000 * 100us");
+    counterUS = 0;
+    }
+  }
+```
+
+## Documentation
+
+### States
+STOPPED / RUNNING / PAUSED
+
+### Constructors / Destructor
+
+**Ticker(fptr callback, uint32_t timer, uint32_t repeats = 0, resolution_t resolution = MICROS)**<br>
+Creates a Ticker object
+- parameter callback for the function name you want to call
+- parameter timer sets the interval time in ms or us when using MICROS_MICROS with the resolution parameter
+- parameter repeats sets the number of repeats the callback should executed, 0 is endless
+- parameter resolution sets the internal resolution of the Ticker, it can MICROS, MICROS_MICROS or MILLIS
+
+**~Ticker()**<br>
+Destructor for Ticker object
+	
+### Functions
+
+**void start()**<br>
+Start the Ticker. Will count the interval from the moment that you start it. If it is paused, it will restart the Ticker.
+
+**void resume()**<br>
+Resume the Ticker. If not started, it will start it. If paused, it will resume it. For example, in a Ticker of 5 seconds, if it was paused at 3 seconds, the resume continues at 3 seconds. Start will set passed time to 0 and restart until it get 5 seconds.
+
+**void pause()**<br>
+Pause the Ticker, so you can resume it.
+
+**void stop()**<br>
+Stop the Ticker.
+
+**void update()**<br>
+Must called in the loop(), it will check the Ticker, and if necessary, will run the callback
+
+**void interval(uint32_t timer)**<br>
+Changes the interval time of the Ticker.
+
+**status_t state()**<br>
+Returns the state of the Ticker.
+
+**uint32_t elapsed()**<br>
+Returns the time passed since the last tick, ms or us depending from the resolution.
+
+**uint32_t counter()**<br>
+Returns the number of executed callbacks.
+
+
+

trunk/Arduino/libraries/Ticker/Ticker.cpp

@@ -0,0 +1,112 @@
+/* Ticker library code is placed under the MIT license
+ * Copyright (c) 2018 Stefan Staub
+ *
+ * Permission is hereby granted, free of charge, to any person obtaining
+ * a copy of this software and associated documentation files (the
+ * "Software"), to deal in the Software without restriction, including
+ * without limitation the rights to use, copy, modify, merge, publish,
+ * distribute, sublicense, and/or sell copies of the Software, and to
+ * permit persons to whom the Software is furnished to do so, subject to
+ * the following conditions:
+ *
+ * The above copyright notice and this permission notice shall be
+ * included in all copies or substantial portions of the Software.
+ *
+ * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
+ * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
+ * MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
+ * NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS
+ * BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN
+ * ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
+ * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+ * SOFTWARE.
+ */
+
+#include "Ticker.h"
+
+Ticker::Ticker(fptr callback, uint32_t timer, uint32_t repeat, resolution_t resolution) {
+	this->resolution = resolution;
+	if (resolution == MICROS) timer = timer * 1000;
+	this->timer = timer;
+	this->repeat = repeat;
+	this->callback = callback;
+	enabled = false;
+	lastTime = 0;
+	counts = 0;
+	}
+
+Ticker::~Ticker() {}
+
+void Ticker::start() {
+	if (callback == NULL) return;
+	if (resolution == MILLIS) lastTime = millis();
+	else lastTime = micros();
+	enabled = true;
+	counts = 0;
+	status = RUNNING;
+	}
+
+void Ticker::resume() {
+	if (callback == NULL) return;
+	if (resolution == MILLIS) lastTime = millis() - diffTime;
+	else lastTime = micros() - diffTime;
+	if (status == STOPPED) counts = 0;
+	enabled = true;
+	status = RUNNING;
+	}
+
+void Ticker::stop() {
+	enabled = false;
+	counts = 0;
+	status = STOPPED;
+	}
+
+void Ticker::pause() {
+	if (resolution == MILLIS) diffTime = millis() - lastTime;
+	else diffTime = micros() - lastTime;
+	enabled = false;
+	status = PAUSED;
+	}
+
+void Ticker::update() {
+	if (tick()) callback();
+	}
+
+bool Ticker::tick() {
+	if (!enabled)	return false;
+	if (resolution == MILLIS) {
+		if ((millis() - lastTime) >= timer) {
+			lastTime = millis();
+			if (repeat - counts == 1) enabled = false;
+			counts++;				
+	  	return true;
+			}
+		}
+	else {
+		if ((micros() - lastTime) >= timer) {
+			lastTime = micros();
+			if (repeat - counts == 1) enabled = false;
+			counts++;
+			return true;
+			}
+		}
+	return false;
+	}
+
+void Ticker::interval(uint32_t timer) {
+	if (resolution == MICROS) timer = timer * 1000;
+	this->timer = timer;
+	}
+
+uint32_t Ticker::elapsed() {
+	if (resolution == MILLIS) return millis() - lastTime;
+	else return micros() - lastTime;
+	}
+
+status_t Ticker::state() {
+	return status;
+	}
+
+uint32_t Ticker::counter() {
+	return counts;
+	}

trunk/Arduino/libraries/Ticker/Ticker.h

@@ -0,0 +1,133 @@
+/* Ticker library code is placed under the MIT license
+ * Copyright (c) 2018 Stefan Staub
+ *
+ * Permission is hereby granted, free of charge, to any person obtaining
+ * a copy of this software and associated documentation files (the
+ * "Software"), to deal in the Software without restriction, including
+ * without limitation the rights to use, copy, modify, merge, publish,
+ * distribute, sublicense, and/or sell copies of the Software, and to
+ * permit persons to whom the Software is furnished to do so, subject to
+ * the following conditions:
+ *
+ * The above copyright notice and this permission notice shall be
+ * included in all copies or substantial portions of the Software.
+ *
+ * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
+ * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
+ * MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
+ * NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS
+ * BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN
+ * ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
+ * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+ * SOFTWARE.
+ */
+
+#ifndef TICKER_H
+#define TICKER_H
+
+#include "Arduino.h"
+
+/** Ticker internal resolution
+ *
+ * @param MICROS default, the resoöution is in micro seconds, max is 70 minutes, the real resoltuion is 4 microseconds at 16MHz CPU cycle
+ * @param MILLIS set the resolution to millis, for longer cycles over 70 minutes
+ *
+ */
+enum resolution_t {MICROS, MILLIS, MICROS_MICROS};
+
+/** Ticker status
+ *
+ * @param STOPPED default, ticker is stopped
+ * @param RUNNIBG ticker is running
+ * @param PAUSED ticker is paused
+ *
+ */
+enum status_t {STOPPED, RUNNING, PAUSED};
+
+typedef void (*fptr)();
+
+class Ticker {
+
+public:
+
+	/** create a Ticker object
+	 *
+	 * @param callback the name of the function to call
+	 * @param timer interval length in ms or us
+	 * @param repeat default 0 -> endless, repeat > 0 -> number of repeats
+	 * @param resolution default MICROS for tickers under 70min, use MILLIS for tickers over 70 min
+	 *
+	 */
+	Ticker(fptr callback, uint32_t timer, uint32_t repeat = 0, resolution_t resolution = MICROS);
+
+	/** destructor for the Ticker object
+	 *
+	 */
+	~Ticker();
+
+	/** start the ticker
+	 *
+	 */
+	void start();
+
+	/** resume the ticker. If not started, it will start it.
+	 *
+	 */
+	void resume();
+
+	/** pause the ticker
+	 *
+	 */
+	void pause();
+
+	/** stops the ticker
+	 *
+	 */
+	void stop();
+
+	/** must to be called in the main loop(), it will check the Ticker, and if necessary, will run the callback
+	 *
+	 */
+	void update();
+
+	/**
+	 * @brief set the interval timer
+	 * 
+	 * @param timer interval length in ms or us
+	 */
+	void interval(uint32_t timer);
+
+	/** actual ellapsed time
+	 *
+	 * @returns the elapsed time after the last tick
+	 *
+	 */
+	uint32_t elapsed();
+
+	/** get the state of the ticker
+	 *
+	 * @returns the state of the ticker: STOPPED, RUNNING or PAUSED
+	 */
+	status_t state();
+
+	/** get the numbers of executed repeats
+	 *
+	 * @returns the number of executed repeats
+	 *
+	 */
+	uint32_t counter();
+
+private:
+	bool tick();
+	bool enabled;
+	uint32_t timer;
+	uint32_t repeat;
+	resolution_t resolution = MICROS;
+	uint32_t counts;
+	status_t status;
+	fptr callback;
+	uint32_t lastTime;
+	uint32_t diffTime;
+};
+
+#endif

trunk/Arduino/libraries/Ticker/examples/Ticker/Ticker.ino

@@ -0,0 +1,65 @@
+#include "Ticker.h"
+
+void printMessage();
+void printCounter();
+void printCountdown();
+void blink();
+void printCountUS();
+
+bool ledState;
+int counterUS;
+
+Ticker timer1(printMessage, 0, 1);
+Ticker timer2(printCounter, 1000, MILLIS);
+Ticker timer3(printCountdown, 1000, 5);
+Ticker timer4(blink, 500);
+Ticker timer5(printCountUS, 100, 0, MICROS_MICROS);
+
+
+void setup() {
+  pinMode(LED_BUILTIN, OUTPUT);
+  Serial.begin(9600);
+  delay(2000);
+  timer1.start();
+  timer2.start();
+  timer3.start();
+  timer4.start();
+  timer5.start();
+  }
+
+void loop() {
+  timer1.update();
+  timer2.update();
+  timer3.update();
+  timer4.update();
+  timer5.update();
+  if (timer4.counter() == 20) timer4.interval(200);
+  if (timer4.counter() == 80) timer4.interval(1000);
+  }
+
+void printCounter() {
+  Serial.print("Counter ");
+  Serial.println(timer2.counter());
+  }
+
+void printCountdown() {
+  Serial.print("Countdowm ");
+  Serial.println(5 - timer3.counter());
+  }
+
+void printMessage() {
+  Serial.println("Hello!");
+  }
+
+void blink() {
+  digitalWrite(LED_BUILTIN, ledState);
+  ledState = !ledState;
+  }
+
+void printCountUS() {
+  counterUS++;  
+  if (counterUS == 10000) {
+    Serial.println("10000 * 100us");
+    counterUS = 0;
+    }
+  }

trunk/Arduino/libraries/Ticker/keywords.txt

@@ -0,0 +1,10 @@
+Ticker 	KEYWORD1
+start	KEYWORD2
+resume	KEYWORD2
+pause	KEYWORD2
+stop	KEYWORD2
+update	KEYWORD2
+interval	KEYWORD2
+state	KEYWORD2
+counter	KEYWORD2
+elapsed	KEYWORD2

trunk/Arduino/libraries/Ticker/library.json

@@ -0,0 +1,14 @@
+{
+  "name": "Ticker",
+  "keywords": "Ticker, Timer, Threads",
+  "description": "A library for creating Tickers which can call repeating functions. Replaces delay() with non-blocking functions.",
+  "repository":
+  {
+    "type": "git",
+    "url": "https://github.com/sstaub/Ticker"
+  },
+  "version": "3.2.0",
+  "frameworks": "arduino",
+  "platforms": "*"
+}
+

trunk/Arduino/libraries/Ticker/library.properties

@@ -0,0 +1,9 @@
+name=Ticker
+version=3.2.0
+author=Stefan Staub
+maintainer=Stefan Staub <email@domain.com>
+sentence=A library for creating Tickers which can call repeating functions. Replaces delay() with non-blocking functions.
+paragraph=The Arduino Ticker Library allows you to create easily Ticker callbacks, which can call a function in a predetermined interval. You can change the number of repeats of the callbacks, if repeats is 0 the ticker runs in endless mode. Works like a "thread", where a secondary function will run when necessary. The library use no interupts of the hardware timers and works with the micros() / millis() function. You are not (really) limited in the number of Tickers.
+category=Timing
+url=https://github.com/sstaub/Ticker
+architectures=*